FAQ/WilliamsSPSS/Filon - CBU statistics Wiki

Upload page content

You can upload content for the page named below. If you change the page name, you can also upload content for another page. If the page name is empty, we derive the page name from the file name.

File to load page content from
Page name
Comment
Finzd thee wrang lelters ino eacuh wosrd

Revision 4 as of 2006-07-17 13:49:52

location: FAQ / WilliamsSPSS / Filon

Cut and paste this syntax into a SPSS syntax window, select all and click the run arrow key. Amend the spreadsheet data as required.

* Dependent Correlation Comparison Program of rab = rxy. 
* Comparing Correlated but Nonoverlapping Correlation Coefficients. 
* Raghunathan, Rosenthal, and Rubin (1996, Psychological Methods, 1, 178-183).  

*Need as input sample sizes plus six offdiagonal correlations (see below)
* can input multiple rows : each row different set of correlations and sample size (n)

*     a    b     x      y
*--------------------------------
*a   1  rab   rax   ray
*b         1    rbx   rby
*x                1     rxy 
*y                         1
***** replace the specimen values below with correlations and sample size of your data******

set format f10.5.
DATA LIST free
/rab  rax  ray  rbx  rby  rxy  n. 
BEGIN DATA
.38 .45 .53 .31 .55 .25 603 
.645 .756 .707 .952 .947 .980 10
END DATA. 
compute #k = (rax-rbx*rab)*(rby-rbx*rxy)+(ray-rax*rxy)*(rbx-rax*rab)+(rax-ray*rxy)*(rby-ray*rab)+(ray-rab*rby)*(rbx-rby*rxy).
compute #pf = (rab-rxy)*sqrt(n)/sqrt((1-rab**2)**2+(1-rxy**2)**2-#k).
compute #p_pf = 2*cdfnorm(-1*abs(#pf)).
compute #zab = 0.5*ln((1+rab)/(1-rab)).
compute #zxy = 0.5*ln((1+rxy)/(1-rxy)).
compute zpf = sqrt((n-3)/2)*(#zab-#zxy)/sqrt(1-(#k/(2*(1-rab**2)*(1-rxy**2)))).
compute p_zpf = 2*cdfnorm(-1*abs(zpf)).

FORMAT rab rxy zpf p_zpf (f9.3).
VARIABLE LABELS rab 'correlation 1' rxy 'correlation 2' /zpf 'z-value' 
/p_zpf '2-tailed p-value'.
EXECUTE.

REPORT FORMAT=LIST AUTOMATIC ALIGN(CENTER)
  /VARIABLES=rab rxy zpf p_zpf 
  /TITLE "Pearson-Filon test of two nonoverlapping correlations".